home *** CD-ROM | disk | FTP | other *** search
/ Mission 3 / Mission 3.zip / Mission 3.iso / zugabe / va45 / visual45 / library / extend / rsc.s < prev    next >
Text File  |  1998-07-25  |  34KB  |  1,376 lines
  1. ;------------------------------------------------------------------------------
  2. ; Method name : -
  3. ; Asm label   : GWVA_RSC_TEST_IF_TEDINFO_STRUCT_EXIST_IDX
  4. ; Description : Indique si l'objet RSC contient une structure TEDINFO
  5. ;
  6. ; Rq  : a0.l/d0.l modifié
  7. ; 
  8. ; in  : a0.l = pointeur sur l'arbre RSC
  9. ; in  : d0.w = index de l'objet RSC
  10. ; out : d7.w = GWVA_NO_ERROR_GENERIC si un TEDINFO existe, GWVA_NO_ERROR_GENERIC sinon
  11. ;
  12. ; 24/05/98 : Création
  13. ;------------------------------------------------------------------------------
  14. GWVA_RSC_TEST_IF_TEDINFO_STRUCT_EXIST_IDX:
  15.     mulu #L_OBJECT,d0
  16.     add.l d0,a0
  17.     bra GWVA_RSC_TEST_IF_TEDINFO_STRUCT_EXIST
  18.  
  19. ;------------------------------------------------------------------------------
  20. ; Method name : -
  21. ; Asm label   : GWVA_RSC_TEST_IF_TEDINFO_STRUCT_EXIST
  22. ; Description : Indique si l'objet RSC contient une structure TEDINFO
  23. ;
  24. ; Rq  : -
  25. ; 
  26. ; in  : a0.l = pointeur sur l'objet RSC
  27. ; out : d7.w = GWVA_NO_ERROR_GENERIC si un TEDINFO existe, GWVA_NO_ERROR_GENERIC sinon
  28. ;
  29. ; 24/05/98 : Création
  30. ;------------------------------------------------------------------------------
  31. GWVA_RSC_TEST_IF_TEDINFO_STRUCT_EXIST:
  32.  
  33.     move.w #GWVA_ERROR_GENERIC,d7
  34.  
  35.     cmp.w #G_TEXT,ob_type(a0)
  36.     beq.s .TEDINFO
  37.     cmp.w #G_BOXTEXT,ob_type(a0)
  38.     beq.s .TEDINFO
  39.     cmp.w #G_FTEXT,ob_type(a0)
  40.     beq.s .TEDINFO
  41.     cmp.w #G_FBOXTEXT,ob_type(a0)
  42.     bne.s .pas_TEDINFO
  43. .TEDINFO:
  44.     move.w #GWVA_NO_ERROR_GENERIC,d7
  45. .pas_TEDINFO:
  46.     rts
  47.  
  48. ;------------------------------------------------------------------------------
  49. ; Method name : -
  50. ; Asm label   : GWVA_RSC_GO_OVER_TREE
  51. ; Description : Parcours un (sous-)arbre et exécute un routine pour chaque objet
  52. ; Description : de cet arbre.
  53. ;
  54. ; Rq  : La routine ne s'arrête qu'une fois tous les objets parcourus ou bien
  55. ; Rq  : jusqu'à ce que la routine renvoit d7.w = GWVA_RSC_CTE_STOP_GO_OVER.
  56. ; Rq  : La routine reçoit les paramètres suivant :
  57. ; Rq  : in  : a0.l = adresse de base de l'arbre (objet #0)
  58. ; Rq  : in  : a1.l = pointeur sur la routine à exécuter (terminée par un RTS)
  59. ; Rq  : in  : a2.l = pointeur sur l'objet courant
  60. ; Rq  : in  : d0.w = index de l'objet courant
  61. ; Rq  : in  : d1.w = index du père de l'objet courant (-1 pour le root)
  62. ; Rq  : La routine doit renvoyer le paramètre :
  63. ; Rq  : out : d7.w = GWVA_RSC_CTE_CONTINUE_GO_OVER ou GWVA_RSC_CTE_STOP_GO_OVER
  64. ;
  65. ; in  : a0.l = adresse de base de l'arbre (objet #0)
  66. ; in  : a1.l = pointeur sur la routine à exécuter (terminée par un RTS)
  67. ; in  : a2.l = pointeur sur l'objet de départ du parcours
  68. ; in  : d0.w = index de l'objet de départ
  69. ; in  : d1.w = index du père de l'objet de départ (-1 pour le root)
  70. ;
  71. ; 23/05/98 : Création
  72. ;------------------------------------------------------------------------------
  73. GWVA_RSC_GO_OVER_TREE:
  74.     link a6,#-(2+4)
  75.     move.w d1,(a7)    ; stock numéro du père
  76. .same_level:
  77.     move.l a2,2(a7)    ; et l'adresse de l'objet courant
  78.  
  79.     save.l a0-a2/a6/d0-d1
  80.     jsr (a1)
  81.     load.l a0-a2/a6/d0-d1
  82.     cmp.w #GWVA_RSC_CTE_STOP_GO_OVER,d7
  83.     beq.s .stop_recursif
  84.  
  85.     move ob_head(a2),d1    ; ai-je un fils ?
  86.     bpl.s .child_exist
  87.  
  88. .continue_brother_father:
  89.     move ob_next(a2),d1    ; ai-je une famille autre que mon père
  90.     move.w d1,d0
  91.  
  92.     cmp.w (a7),d1
  93.     beq.s .back_2_father
  94.  
  95.     mulu #L_OBJECT,d1
  96.     lea (a0,d1.l),a2
  97.     bra.s .same_level
  98.  
  99. .child_exist:
  100.     move.w d1,d2    ; d2.w : fils
  101.     mulu #L_OBJECT,d1
  102.     lea (a0,d1.l),a2
  103.     move.w d0,d1    ; d1.w : l'ancien père c'est moi
  104.     move.w d2,d0    ; d0.w ; courant = fils
  105.     bsr GWVA_RSC_GO_OVER_TREE
  106.     move.l 2(a7),a2    ; mon adresse
  107.     cmp.w #GWVA_RSC_CTE_STOP_GO_OVER,d7
  108.     bne.s .continue_brother_father
  109.     bra.s .stop_recursif
  110.  
  111. .back_2_father:
  112.     move.w #GWVA_RSC_CTE_CONTINUE_GO_OVER,d7
  113. .stop_recursif:
  114.     unlk a6
  115.     rts
  116.  
  117. ;------------------------------------------------------------------------------
  118. ; Method name : -
  119. ; Asm label   : GWVA_RSC_ENABLE_DISABLE_OBJECT
  120. ; Description : active/déactive un objet GEM
  121. ; 
  122. ; in  : d0.w = index du formulaire
  123. ; in  : d1.w = index de l'objet
  124. ; in  : d2.w = nouvel état désiré (0 : enable, 1 : disable)
  125. ;
  126. ; 19/03/98 : Création
  127. ;------------------------------------------------------------------------------
  128. GWVA_RSC_ENABLE_DISABLE_OBJECT:    ; d0.w : numéro du formulaire, d1.w : numéro de l'objet, d2=nouvel état (1=disable)
  129.  
  130.     save.w d2
  131.     bsr GWVA_RSC_RETURN_PTR_ON_OBJ
  132.     load.w d2
  133.  
  134.     bclr #DISABLED,ob_state+1(a1)
  135.     tst d2
  136.     beq.s .cleared
  137.     bset #DISABLED,ob_state+1(a1)
  138. .cleared:    rts
  139.  
  140. ;------------------------------------------------------------------------------
  141. ; Method name : -
  142. ; Asm label   : GWVA_RSC_RETURN_OBJ_POS_SIZE
  143. ; Description : Renvoie la position et la taille "vraies" d'un objet GEM, 
  144. ; Description : sculptures comprises
  145. ; 
  146. ; Rq  : Problèmes si les sculptures d'un fils dépassent de son père
  147. ;
  148. ; in  : a0.l = pointeur sur l'arbre
  149. ; in  : d0.w = index de l'objet
  150. ; out : a0.l = pointeur sur l'objet
  151. ; out : d0-d3.w = x,y,w,h réelle de l'objet
  152. ;
  153. ; 19/03/98 : Création
  154. ;------------------------------------------------------------------------------
  155. GWVA_RSC_RETURN_OBJ_POS_SIZE:
  156.  
  157.     move.w d0,d7    ; pour plus tard ...
  158.     move.l a0,a1    ; pour plus tard ...
  159.  
  160.     mulu #L_OBJECT,d0
  161.     lea (a0,d0.l),a0    ; ptr sur l'objet GEM
  162.  
  163.     clr.w d0
  164.     move.b ob_type+1(a0),d0    ; type de l'objet
  165.  
  166.     clr.w d1        ; épaisseur bord gauche
  167.     clr.w d2        ; épaisseur bord droit
  168.     clr.w d3        ; épaisseur bord haut
  169.     clr.w d4        ; épaisseur bord bas
  170.  
  171.     cmp.w #G_BOX,d0
  172.     beq .taille_bord_dans_ob_spec
  173.     cmp.w #G_IBOX,d0
  174.     beq .taille_bord_dans_ob_spec
  175.     cmp.w #G_BOXCHAR,d0
  176.     beq .taille_bord_dans_ob_spec
  177.  
  178.     cmp.w #G_BOXTEXT,d0
  179.     beq .taille_bord_dans_structure_ob_spec
  180.     cmp.w #G_FBOXTEXT,d0
  181.     beq .taille_bord_dans_structure_ob_spec
  182.  
  183. .tests_ob_state:
  184.     move.w ob_state(a0),d0
  185.  
  186.     btst #OUTLINED,d0
  187.     beq.s .pas_outlined
  188.  
  189.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_OUTLINED,d1
  190.     bge.s .taille_prise_en_compte
  191.     move.w #GWVA_RSC_CTE_EPAISSEUR_OUTLINED,d1
  192.     move.w #GWVA_RSC_CTE_EPAISSEUR_OUTLINED,d2
  193.     move.w #GWVA_RSC_CTE_EPAISSEUR_OUTLINED,d3
  194.     move.w #GWVA_RSC_CTE_EPAISSEUR_OUTLINED,d4
  195. .taille_prise_en_compte:
  196. .pas_outlined:
  197.  
  198.     btst #SHADOWED,d0
  199.     beq.s .pas_shadowed
  200.  
  201.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_SHADOWED,d2
  202.     bge.s .taille_prise_en_compte2a
  203.     move.w #GWVA_RSC_CTE_EPAISSEUR_SHADOWED,d2
  204. .taille_prise_en_compte2a:
  205.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_SHADOWED,d4
  206.     bge.s .taille_prise_en_compte2b
  207.     move.w #GWVA_RSC_CTE_EPAISSEUR_SHADOWED,d4
  208. .taille_prise_en_compte2b:
  209. .pas_shadowed:
  210.  
  211.     move.w GWVA_ROOT_SYSTEM_AES_3D_VBORDER,d5
  212.     move.w GWVA_ROOT_SYSTEM_AES_3D_HBORDER,d6
  213.  
  214.     move.w ob_flags(a0),d0
  215.  
  216.     and.w #MASK_FL3DIND|MASK_FL3DBAK,d0    ; on garde que les bits 3D
  217.  
  218.     cmp.w #MASK_FL3DIND,d0
  219.     beq.s .bit_indicateur3D
  220.     cmp.w #MASK_FL3DACT,d0
  221.     bne.s .pas_activateur3D
  222. .bit_indicateur3D:
  223.     cmp.w d5,d1
  224.     bge.s .taille_prise_en_compte3a
  225.     move.w d5,d1
  226. .taille_prise_en_compte3a:
  227.     cmp.w d5,d2
  228.     bge.s .taille_prise_en_compte3b
  229.     move.w d5,d2
  230. .taille_prise_en_compte3b:
  231.  
  232.     cmp.w d6,d3
  233.     bge.s .taille_prise_en_compte4a
  234.     move.w d6,d3
  235. .taille_prise_en_compte4a:
  236.     cmp.w d6,d4
  237.     bge.s .taille_prise_en_compte4b
  238.     move.w d6,d4
  239. .taille_prise_en_compte4b:
  240. .pas_activateur3D:
  241.  
  242.     tst.w d1
  243.     bge.s .bord_gauche_positif
  244.     clr.w d1
  245. .bord_gauche_positif:
  246.     tst.w d2
  247.     bge.s .bord_droit_positif
  248.     clr.w d2
  249. .bord_droit_positif:
  250.     tst.w d3
  251.     bge.s .bord_haut_positif
  252.     clr.w d3
  253. .bord_haut_positif:
  254.     tst.w d4
  255.     bge.s .bord_bas_positif
  256.     clr.w d4
  257. .bord_bas_positif:
  258.  
  259.     clr.w d0
  260.     move.b ob_type+1(a0),d0
  261.  
  262.     cmp.w #G_BUTTON,d0
  263.     bne.s .pas_tests_bouton
  264.  
  265.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d1    ; taille de 1 en plus de base pour les boutons
  266.     bge.s .taille_prise_en_compte7a
  267.     move.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d1
  268. .taille_prise_en_compte7a:
  269.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d2
  270.     bge.s .taille_prise_en_compte7b
  271.     move.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d2
  272. .taille_prise_en_compte7b:
  273.  
  274.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d3
  275.     bge.s .taille_prise_en_compte8a
  276.     move.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d3
  277. .taille_prise_en_compte8a:
  278.     cmp.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d4
  279.     bge.s .taille_prise_en_compte8b
  280.     move.w #GWVA_RSC_CTE_EPAISSEUR_G_BUTTON,d4
  281. .taille_prise_en_compte8b:
  282.  
  283.     move.w ob_flags(a0),d0
  284.  
  285.     btst #MASK_DEFAULT,d0
  286.     beq.s .pas_defaut
  287.     addq.w #1,d1        ; se rajoute à tout
  288.     addq.w #1,d2
  289.     addq.w #1,d3
  290.     addq.w #1,d4
  291. .pas_defaut:
  292.     btst #MASK_EXIT,d0
  293.     beq.s .pas_exit
  294.     addq.w #1,d1        ; se rajoute à tout
  295.     addq.w #1,d2
  296.     addq.w #1,d3
  297.     addq.w #1,d4
  298. .pas_exit:
  299. .pas_tests_bouton:
  300.  
  301.     save.l d0-d4/a0
  302.     objc_offset a1,d7
  303.     load.l d0-d4/a0
  304.  
  305.     movem.w int_out+1*2,d5-d6
  306.     sub.w d1,d5
  307.     sub.w d3,d6
  308.     add.w d1,d2
  309.     add.w d4,d3
  310.     add.w ob_width(a0),d2
  311.     add.w ob_height(a0),d3
  312.     move.w d5,d0
  313.     move.w d6,d1
  314.  
  315.     rts
  316.  
  317. .taille_bord_dans_ob_spec:
  318.     move.b ob_spec+1(a0),d1        ; epaisseur signée de la bordure
  319.     ext.w d1
  320.     neg.w d1
  321.     move.w d1,d2
  322.     move.w d1,d3
  323.     move.w d1,d4
  324.     bra .tests_ob_state
  325. .taille_bord_dans_structure_ob_spec:
  326.     move.w ([a0,ob_spec],te_thickness),d1    ; epaisseur signée de la bordure
  327.     neg.w d1
  328.     move.w d1,d2
  329.     move.w d1,d3
  330.     move.w d1,d4
  331.     bra .tests_ob_state
  332.  
  333. ;------------------------------------------------------------------------------
  334. ; Method name : -
  335. ; Asm label   : GWVA_RSC_RETURN_PTR_ON_TEXT
  336. ; Description : Renvoie les tailles courantes et max. d'un objet RSC contenant du texte.
  337. ; 
  338. ; in  : d0.w = numéro formulaire 
  339. ; in  : d1.w = numéro de l'objet avec ted info : G_TEXT ou G_BOXTEXT ou G_FTEXT 
  340. ;       ou G_FBOXTEXT ou sans : G_STRING ... etc ...
  341. ; out : a0.l = pointeur sur l'objet RSC
  342. ; out : a1.l = pointeur sur le texte
  343. ;
  344. ; 01/02/98 : Création
  345. ;------------------------------------------------------------------------------
  346. GWVA_RSC_RETURN_PTR_ON_TEXT:
  347.  
  348.     bsr GWVA_RSC_RETURN_PTR_ON_OBJ
  349.     move.l a1,a0
  350.  
  351.     move ob_type(a1),d0
  352.     and.w #$ff,d0
  353.     cmp.w #G_TEXT,d0
  354.     beq.s .theres_ted_info
  355.     cmp.w #G_BOXTEXT,d0
  356.     beq.s .theres_ted_info
  357.     cmp.w #G_FTEXT,d0
  358.     beq.s .theres_ted_info
  359.     cmp.w #G_FBOXTEXT,d0
  360.     beq.s .theres_ted_info
  361.  
  362.     move.l ob_spec(a1),a1    ; a1.l = pointeur du texte voulu
  363.     rts
  364. .theres_ted_info:
  365.     move.l ob_spec(a1),a1
  366.     move.l te_ptext(a1),a1    ; a1.l = pointeur du texte voulu
  367.     rts
  368.  
  369. ;------------------------------------------------------------------------------
  370. ; Method name : -
  371. ; Asm label   : GWVA_RSC_COUNT_TEXT_OBJ_LENGTH
  372. ; Description : Renvoie les tailles courantes et max. d'un objet RSC contenant du texte.
  373. ; 
  374. ; in  : d0.w = numéro formulaire 
  375. ; in  : d1.w = numéro de l'objet avec ted info : G_TEXT ou G_BOXTEXT ou G_FTEXT 
  376. ;       ou G_FBOXTEXT ou sans : G_STRING ... etc ...
  377. ; out : a0.l = pointeur sur le texte
  378. ; out : a1.l = pointeur sur l'objet ressource
  379. ; out : d0.l = taille courante du texte dans le champs (éventuellement éditable)
  380. ; out : d1.w = taille maximale du texte possible (n'a de sens que pour les textes éditables)
  381. ;
  382. ; 01/02/98 : Création
  383. ;------------------------------------------------------------------------------
  384. GWVA_RSC_COUNT_TEXT_OBJ_LENGTH:
  385.     bsr.s GWVA_RSC_RETURN_PTR_ON_TEXT
  386.     exg.l a1,a0
  387.     bsr GWVA_COUNT_BYTES_0
  388.     move d0,d1        ; par défaut, la longueur max est la longueur
  389.             ; courante
  390.     move ob_type(a1),d2
  391.     and.w #$ff,d2
  392.     cmp.w #G_TEXT,d2
  393.     beq.s .theres_ted_info
  394.     cmp.w #G_BOXTEXT,d2
  395.     beq.s .theres_ted_info
  396.     cmp.w #G_FTEXT,d2
  397.     beq.s .theres_ted_info
  398.     cmp.w #G_FBOXTEXT,d2
  399.     beq.s .theres_ted_info
  400.  
  401.     rts
  402. .theres_ted_info:
  403.     move.w ([a1,ob_spec],te_txtlen),d1    ; longueur du texte max
  404.     subq #1,d1            ; moins le 0
  405.     rts
  406.  
  407.     ifd LIB_MODAL_FORMULARY
  408.  
  409. ;------------------------------------------------------------------------------
  410. ; Method name : -
  411. ; Asm label   : GWVA_RSC_MODAL_FORM
  412. ; Description : Fonction pour l'affichage d'un formulaire modal
  413. ; 
  414. ; in  : d0.w = numéro formulaire 
  415. ; out : d0.w = objet EXIT ou TOUCHEXIT
  416. ;
  417. ; 31/01/98 : Création
  418. ;------------------------------------------------------------------------------
  419. GWVA_RSC_MODAL_FORM:
  420.  
  421.     lea GWVA_RSC_TMP_ADD_TREE,a0
  422.     bsr GWVA_RSC_RETURN_PTR_ON_TREE
  423.  
  424.     ifd MDL_COLORS
  425.  
  426.     lea GWVA_ROOT_TMP_PALETTE,a0
  427.     bsr GWVA_ROOT_STORE_VDI_PALETTE
  428.     bsr GWVA_ROOT_SET_DESK_PALETTE
  429.  
  430.     endc    ; ifd MDL_COLORS
  431.  
  432.     wind_update #BEG_UPDATE
  433.     wind_update #BEG_MCTRL
  434.  
  435.     form_center GWVA_RSC_TMP_ADD_TREE
  436.     movem.w int_out+1*2,d1-d4
  437.  
  438.     save.w d1-d4
  439.     graf_mouse #M_OFF
  440.     movem.w (sp),d1-d4
  441.     form_dial #FMD_START,#0,#0,#0,#0,d1,d2,d3,d4
  442.     movem.w (sp),d1-d4
  443.     form_dial #FMD_GROW,#0,#0,#10,#10,d1,d2,d3,d4
  444.     movem.w (sp),d1-d4
  445.     objc_draw GWVA_RSC_TMP_ADD_TREE,#0,#12,d1,d2,d3,d4
  446.     graf_mouse #M_ON
  447.  
  448.     form_do GWVA_RSC_TMP_ADD_TREE,#0
  449.     load.w d1-d4
  450.     save.w d0-d4
  451.     move.l GWVA_RSC_TMP_ADD_TREE,a0
  452.     move d0,d1
  453.     mulu #L_OBJECT,d1
  454.     bclr #SELECTED,ob_state+1(a0,d1.l)    ; de-selected
  455.  
  456.     graf_mouse #M_OFF
  457.     movem.w (sp),d0-d4
  458.     form_dial #FMD_SHRINK,#0,#0,#10,#10,d1,d2,d3,d4
  459.     movem.w (sp),d0-d4
  460.     form_dial #FMD_FINISH,#0,#0,#0,#0,d1,d2,d3,d4
  461.     graf_mouse #M_ON
  462.  
  463.     wind_update #END_MCTRL
  464.     wind_update #END_UPDATE
  465.  
  466.     ifd MDL_COLORS
  467.  
  468.     lea GWVA_ROOT_TMP_PALETTE,a0
  469.     bsr GWVA_ROOT_SET_VDI_PALETTE
  470.  
  471.     endc    ; ifd MDL_COLORS
  472.  
  473.     load.w d0-d4
  474.     rts
  475.  
  476.      endc    ; ifd LIB_MODAL_FORMULARY
  477.  
  478. ;------------------------------------------------------------------------------
  479. ; Method name : -
  480. ; Asm label   : GWVA_RSC_ALERT_BOX
  481. ; Description : Fonction pour l'affichage d'une boite d'alerte à partir d'un ressource
  482. ;
  483. ; in  : d0.w = numéro de l'alert box dans le ressource
  484. ; in  : d1.w = numero du bouton par défaut gauche(1)->milieu(2)->droite(3)
  485. ; out : d0.w = numéro du bouton pressé
  486. ;
  487. ; 31/01/98 : Création
  488. ;------------------------------------------------------------------------------
  489. GWVA_RSC_ALERT_BOX:
  490.  
  491.     save.w d1
  492.     rsrc_gaddr #5,d0    ; R_STRING : Free String Data
  493.     move.l addr_out,a0
  494.     load.w d0
  495.  
  496.     bsr GWVA_ROOT_PRG_ALERT_BOX
  497.  
  498.     rts
  499.  
  500. ;------------------------------------------------------------------------------
  501. ; Method name : -
  502. ; Asm label   : GWVA_RSC_RETURN_PTR_ON_TREE
  503. ; Description : Renvoie un pointeur sur un arbre RSC
  504. ;
  505. ; in  : a0.l = adresse de stockage de l'adresse de base du formulaire
  506. ; in  : d0.w = numéro du formulaire
  507. ; out : (a0) = pointeur sur l'arbre
  508. ; out : d0.w = 0 si erreur, <> 0 sinon.
  509. ;
  510. ; 11/01/98 : Création
  511. ;------------------------------------------------------------------------------
  512. GWVA_RSC_RETURN_PTR_ON_TREE:
  513.  
  514.     save.l a0
  515.     rsrc_gaddr #0,d0    ; En retour, d0<>0 = Ok
  516.     load.l a0
  517.     move.l addr_out,(a0)
  518.     rts
  519.  
  520. ;------------------------------------------------------------------------------
  521. ; Method name : -
  522. ; Asm label   : GWVA_RSC_RETURN_PTR_ON_OBJ
  523. ; Description : Renvoie un pointeur sur un objet RSC dans un formulaire
  524. ;
  525. ; in  : d0.w = numéro du formulaire
  526. ; in  : d1.w = numéro de l'objet
  527. ; out : a1.l = pointeur sur l'objet GEM
  528. ;
  529. ; 11/01/98 : Création
  530. ;------------------------------------------------------------------------------
  531. GWVA_RSC_RETURN_PTR_ON_OBJ:
  532.  
  533.     save.w d1
  534.     lea GWVA_RSC_TMP_ADD_TREE,a0
  535.     bsr.s GWVA_RSC_RETURN_PTR_ON_TREE
  536.     move.l (a0),a1
  537.     load.w d0
  538.     mulu #L_OBJECT,d0
  539.     add.l d0,a1
  540.     rts
  541.  
  542. *-----
  543.     ifd MDL_MENU
  544.  
  545. ;------------------------------------------------------------------------------
  546. ; Method name : -
  547. ; Asm label   : GWVA_RSC_FIND_SON_OBJECT_FROM_ORDINAL
  548. ; Description : retourne un pointeur sur le fils No X d'un père
  549. ;
  550. ; in  : a0.l = pointeur sur un tree
  551. ; in  : d0.w = ordinal du fils (0,...) recherché
  552. ; in  : d1.w = index du père
  553. ; out : a0.l = pointeur sur le fils recherché
  554. ; out : d0.w = index du fils recherché
  555. ; out : d7.w = GWVA_ERROR_GENERIC si pas dans la liste des fils
  556. ;
  557. ; 17/01/98 : Création
  558. ;------------------------------------------------------------------------------
  559. GWVA_RSC_FIND_SON_OBJECT_FROM_ORDINAL:
  560.  
  561.     move d1,d2
  562.     mulu #L_OBJECT,d2
  563.     lea 0(a0,d2.l),a1
  564.     move.w ob_head(a1),d3
  565.     bmi.s .pas_trouve_fils
  566.     sub.w #1,d0
  567.     bmi.s .trouve_fils
  568.  
  569. .boucle:    mulu #L_OBJECT,d3
  570.     lea 0(a0,d3.l),a1
  571.     move ob_next(a1),d3
  572.     cmp.w d1,d3
  573.     beq.s .pas_trouve_fils
  574.     sub.w #1,d0
  575.     bpl.s .boucle
  576. .trouve_fils:
  577.     move.w d3,d0
  578.     mulu #L_OBJECT,d3
  579.     lea 0(a0,d3.l),a0
  580.     moveq #GWVA_NO_ERROR_GENERIC,d7
  581.     rts
  582. .pas_trouve_fils:
  583.     moveq #GWVA_ERROR_GENERIC,d7
  584.     rts
  585.  
  586. ;------------------------------------------------------------------------------
  587. ; Method name : -
  588. ; Asm label   : GWVA_RSC_FIND_ORDINAL_SON_OBJECT
  589. ; Description : renvoie le No ordinal d'un fils par rapport à son père
  590. ;
  591. ; in  : a0.l = pointeur objet root d'un form
  592. ; in  : d0.w = numéro du fils
  593. ; in  : d1.w = numéro du père
  594. ; out : a0.l = pointeur sur le fils
  595. ; out : d0.w = ordinal du fils (0,...)
  596. ; out : d7.w = GWVA_NO_ERROR_GENERIC si OK
  597. ;       ou GWVA_ERROR_GENERIC si pas dans la liste des fils
  598. ;
  599. ; 14/02/98 : Création
  600. ;------------------------------------------------------------------------------
  601. GWVA_RSC_FIND_ORDINAL_SON_OBJECT:
  602.  
  603.     move d1,d2
  604.     mulu #L_OBJECT,d2
  605.     lea 0(a0,d2.l),a1
  606.     moveq #0,d4        ; 1er fils
  607.     move.w ob_head(a1),d3
  608.     bmi.s .pas_de_fils
  609.     cmp.w d0,d3
  610.     beq.s .trouve_fils
  611.  
  612. .boucle:    mulu #L_OBJECT,d3
  613.     lea 0(a0,d3.l),a1
  614.     add.w #1,d4
  615.  
  616.     move ob_next(a1),d3
  617.     cmp.w d1,d3        ; on est revenu au père : erreur
  618.     beq.s .pas_trouve_fils
  619.     cmp.w d0,d3
  620.     bne.s .boucle
  621. .trouve_fils:
  622.     mulu #L_OBJECT,d3
  623.     lea 0(a0,d3.l),a0
  624.     move.w d4,d0
  625.     moveq #GWVA_NO_ERROR_GENERIC,d7
  626.     rts
  627. .pas_de_fils:
  628. .pas_trouve_fils:
  629.     moveq #GWVA_ERROR_GENERIC,d7
  630.     rts
  631.  
  632.     endc    ; ifd MDL_MENU
  633.  
  634.     ifd MDL_GEM        ; en ont besoin : le menu et l'objet popup
  635.  
  636. ;------------------------------------------------------------------------------
  637. ; Method name : -
  638. ; Asm label   : GWVA_RSC_FIND_FATHER_OBJECT
  639. ; Description : renvoie l'index du père d'un objet
  640. ;
  641. ; in  : a0.l : pointeur objet root d'un form
  642. ; in  : d0.w : numéro du fils dont on cherche le père
  643. ; out : a0.l : pointeur sur cet objet (le père)
  644. ; out : d0.w : index du père
  645. ; out : d7.w = GWVA_NO_ERROR_GENERIC si OK
  646. ;       ou GWVA_ERROR_GENERIC si pas de père
  647. ;
  648. ; 14/02/98 : Création
  649. ;------------------------------------------------------------------------------
  650. GWVA_RSC_FIND_FATHER_OBJECT:
  651.  
  652.     tst d0
  653.     beq.s .root
  654.  
  655.     move d0,d1
  656.     mulu #L_OBJECT,d1
  657.     lea 0(a0,d1.l),a1
  658.     move d0,d1        ; d0=courant d1=précédent
  659.  
  660. .boucle:    move ob_next(a1),d0
  661.     move d0,d2
  662.     mulu #L_OBJECT,d2
  663.     lea 0(a0,d2.l),a1    ; a1 : adresse de l'objet courant
  664.     cmp ob_tail(a1),d1    ; est-ce que ob_tail obj suivant = nous ?
  665.     beq.s .found_father
  666.     move d0,d1        ; nouveau précédent = courant pour la suite
  667.     bra.s .boucle
  668. .found_father:
  669.     move.l a1,a0
  670.     moveq #GWVA_NO_ERROR_GENERIC,d7
  671.     rts
  672.  
  673. .root:    moveq #GWVA_ERROR_GENERIC,d7
  674.     rts
  675.  
  676.     endc    ; ifd MDL_GEM
  677.  
  678.     ifd MDL_WIND_MENU
  679.  
  680. ;------------------------------------------------------------------------------
  681. ; Method name : -
  682. ; Asm label   : GWVA_RSC_SHOW_HIDE_TREE
  683. ; Description : montre ou cache un arbre
  684. ;
  685. ; in  : d0.w : index du tree
  686. ; in  : d1.w : index de l'objet RSC
  687. ; in  : d2.w : nouvel état 0 = show, 1 = hide
  688. ; out : a0.l : pointeur sur le fils recherché
  689. ; out : d0.w : index du fils à cacher/montrer
  690. ; out : d7.w : GWVA_ERROR_GENERIC si pas dans la liste des fils
  691. ;
  692. ; 17/01/98 : Création
  693. ;------------------------------------------------------------------------------
  694. GWVA_RSC_SHOW_HIDE_TREE:
  695.  
  696.     save.w d2
  697.     bsr GWVA_RSC_RETURN_PTR_ON_OBJ
  698.     load.w d2
  699.  
  700.     bclr #HIDETREE,ob_flags+1(a1)
  701.     tst d2
  702.     beq.s .cleared
  703.     bset #HIDETREE,ob_flags+1(a1)
  704. .cleared:    rts
  705.  
  706.     endc    ; ifd MDL_WIND_MENU
  707.  
  708.     ifd MDL_RELOCATE_RSC
  709.  
  710.   ifnd LIB_SEARCH_SYSTEM_COOKIES
  711.    ifnd LIB_SEARCH_COOKIES
  712.     ifd OPT_GWVA_DEBUG_PRINT_COMMENTS
  713.    LIST
  714. ;------------------------------------------------------------------------------
  715. ; Rq  : Lorsque vous utilisez MDL_RELOCATE_RSC, définir LIB_SEARCH_SYSTEM_COOKIES
  716. ; Rq  : ou au moins LIB_COOKIE pour permettre d'utiliser les nouvelles 
  717. ; Rq  : fonctionnalités de l'AES 4.
  718. ;------------------------------------------------------------------------------
  719.    NOLIST
  720.     endc
  721.    endc
  722.   endc
  723.  
  724. ;------------------------------------------------------------------------------
  725. ; Method name : -
  726. ; Asm label   : GWVA_RSC_RELOCATE_RSC
  727. ; Description : Fonction faisant la relocation d'un ressource en mémoire
  728. ; Description : et permettant au système de l'utiliser normalement
  729. ;
  730. ; in  : a0.l = pointeur sur le ressource en mémoire
  731. ; out : d7.w = GWVA_NO_ERROR_GENERIC ou GWVA_ERROR_GENERIC
  732. ;
  733. ; 11/01/98 : Création
  734. ;------------------------------------------------------------------------------
  735. GWVA_RSC_RELOCATE_RSC:
  736.  
  737.     cmp.l #0,a0
  738.     ble .erreur_ressource
  739.  
  740.     ifnd LIB_SEARCH_SYSTEM_COOKIES
  741.  
  742.     ifd LIB_COOKIE
  743.  
  744.     move.l #"MagX",GWVA_ROOT_SEARCH_IN_OUT
  745.     save.l a0
  746.     SUPEXEC GWVA_COOKIE_SEARCH_ONE_COOKIE
  747.     load.l a0
  748.     tst.l GWVA_ROOT_SEARCH_IN_OUT
  749.     beq.s .magic_not_present
  750.  
  751.     endc    ; ifd LIB_COOKIE
  752.     else
  753.  
  754.     tst.l GWVA_ROOT_COOKIE_MAGIC    ; l'AES de MagiC est le 3.99 mais il supporte rsrc_rcfix ...
  755.     bne.s .magic_present
  756.     endc    ; ifnd LIB_SEARCH_SYSTEM_COOKIES
  757.  
  758. .magic_not_present:
  759.     cmp.w #$400,global+_AESversion
  760.     blt.s .pas_AES400
  761.  
  762. .magic_present:
  763.  
  764.     rsrc_rcfix a0    ; supporte tous les formats, plus rapide ...
  765.     tst d0
  766.     beq .erreur_ressource
  767.  
  768.     moveq #GWVA_NO_ERROR_GENERIC,d7
  769.     rts
  770.  
  771. .erreur_ressource:
  772.     moveq #GWVA_ERROR_GENERIC,d7
  773.     rts
  774.  
  775. .pas_AES400:
  776.     ; a0.l
  777.     lea GWVA_ROOT_ADD_MALLOC_RSC_ICN,a1
  778.     bsr GWVA_RSC_RELOCATE_RSC_IN_MEM
  779.     cmp.w #GWVA_NO_ERROR_GENERIC,d7
  780.     bne.s .erreur_ressource
  781.  
  782.     move.l a0,a1
  783.     add.w #L_RSC_HEADER,a1
  784.     move.l a1,global+_AESrscfile    ; on stocke l'adresse du début du ressource (documenté)
  785.     move.l a0,global+_AESrscfile+4    ; on stocke l'adresse du début du fichier RSC (non documenté)
  786.     move.w rsh_rssize(a0),global+_AESrscfile+4+4    ; on stocke la taille du ressource (non documenté)
  787.     move.w rsh_vrsn(a0),global+_AESrscfile+4+4+2    ; on stocke la version du ressource (non documenté)
  788.  
  789.     btst #2,rsh_vrsn+1(a0)
  790.     beq.s .old_rsc2
  791. ; Là je sais pas si on doit stocker un mauvaise taille dans le cas d'un
  792. ; formulaire pour l'AES 3.3 ???
  793.     move.l a0,a1
  794.     add.w rsh_rssize(a0),a1
  795.     move.w 2(a1),global+_AESrscfile+4+4
  796. .old_rsc2:
  797.     moveq #GWVA_NO_ERROR_GENERIC,d7
  798.     rts
  799.  
  800. ;------------------------------------------------------------------------------
  801. ; Method name : -
  802. ; Asm label   : GWVA_RSC_RELOCATE_RSC_IN_MEM
  803. ; Description : Fonction faisant uniquement la relocation d'un ressource en mémoire
  804. ;
  805. ; in  : a0.l = pointeur sur le ressource en mémoire
  806. ; in  : a1.l = pointeur sur 2 mots long (pour le traitement des icones couleurs)
  807. ;       le premier contiendra l'adresse du MALLOC des icones couleurs, 0.l sinon.
  808. ;       Au programmeur de libérer cet espace mémoire lorsqu'il n'a plus besoin
  809. ;       du ressource
  810. ; out : d7.w = GWVA_NO_ERROR_GENERIC ou erreur 
  811. ;
  812. ; 11/01/98 : Création
  813. ;------------------------------------------------------------------------------
  814. GWVA_RSC_RELOCATE_RSC_IN_MEM:
  815.  
  816.     move.l a0,d0
  817.     btst #0,d0
  818.     beq.s .rsc_sur_adresse_paire
  819.     ifd OPT_GWVA_DEBUG_ERROR
  820.     lea GWVA_ASCII_ERROR_RSC_ON_ODD_ADDRESS,a6
  821.     illegal
  822.     endc
  823.     bra .erreur_ressource
  824. .rsc_sur_adresse_paire:
  825.  
  826.     clr.l (a1)
  827.     clr.l 4(a1)
  828.  
  829.     tst.w rsh_vrsn(a0)
  830.     beq .old_format
  831.     cmp.w #1,rsh_vrsn(a0)
  832.     beq .old_format
  833.     btst #2,rsh_vrsn+1(a0)
  834.     beq .erreur_ressource
  835.  
  836.     ; New format !
  837.     ; Ne gere pas le format étendu : rsh_vrsn = $0003
  838.  
  839.     bsr .traitement_icones_couleurs
  840.  
  841. .old_format:
  842.     ; fin du traitement des icones couleur, ouf !
  843.  
  844.     move.w #rsh_frstr,d1
  845.     move rsh_nstring(a0),d0
  846.     bsr .reloc_array
  847.     move.w #rsh_frimg,d1
  848.     move rsh_nimages(a0),d0
  849.     bsr .reloc_array
  850.     move.w #rsh_trindex,d1
  851.     move rsh_ntree(a0),d0
  852.     bsr .reloc_array
  853.  
  854.     ; reloc la table des teds_info
  855.     move.l a0,a1
  856.     move.l a0,d7
  857.     add.w rsh_tedinfo(a0),a1
  858.     move rsh_nted(a0),d0
  859.     subq #1,d0
  860.     bmi.s .nothing1
  861. .reloc_ptrs_ted:
  862.     add.l d7,te_ptext(a1)
  863.     add.l d7,te_ptmplt(a1)
  864.     add.l d7,te_pvalid(a1)
  865.     lea L_TEDINFO(a1),a1
  866.     dbf d0,.reloc_ptrs_ted
  867. .nothing1:
  868.     ; reloc la table des icon_blk
  869.     move.l a0,a1
  870.     move.l a0,d7
  871.     add.w rsh_iconblk(a0),a1
  872.     move rsh_nib(a0),d0
  873.     subq #1,d0
  874.     bmi.s .nothing2
  875. .reloc_ptrs_iconblk:
  876.     add.l d7,ib_pmask(a1)
  877.     add.l d7,ib_pdata(a1)
  878.     add.l d7,ib_ptext(a1)
  879.     lea L_ICONBLK(a1),a1
  880.     dbf d0,.reloc_ptrs_iconblk
  881. .nothing2:
  882.     ; reloc la table des bit_blk
  883.     move.l a0,a1
  884.     move.l a0,d7
  885.     add.w rsh_bitblk(a0),a1
  886.     move rsh_nbb(a0),d0
  887.     subq #1,d0
  888.     bmi.s .nothing3
  889. .reloc_ptrs_bitblk:
  890.     add.l d7,bi_pdata(a1)
  891.     lea L_BITBLK(a1),a1
  892.     dbf d0,.reloc_ptrs_bitblk
  893. .nothing3:
  894.     ; reloc la table des cicon_blk
  895.  
  896.     ; parse tous les objets
  897.     move rsh_ntree(a0),d0
  898.     subq #1,d0
  899.     bmi .nothing4
  900.  
  901.     move.l a0,a1
  902.     move.l a0,d7
  903.     add.w rsh_trindex(a0),a1
  904.  
  905. .parse_all_trees:
  906.     move.l (a1)+,a2
  907.  
  908.     move #1-1,d1
  909.     tst ob_tail(a2)
  910.     bmi.s .pas_de_fils
  911.     move ob_tail(a2),d1    ; +1 pour le père -1 pour dbf
  912. .pas_de_fils:
  913.  
  914.     clr d2        ; No objet = pere
  915. .parse_all_this_tree:        ; -4(a1) =ptr tree a2=ptr object
  916.  
  917.     move.w ob_type(a2),d3
  918.     and.w #$ff,d3
  919.  
  920.     cmp.w #G_TEXT,d3
  921.     beq.s .reloc_ted
  922.     cmp.w #G_BOXTEXT,d3
  923.     beq.s .reloc_ted
  924.     cmp.w #G_FTEXT,d3
  925.     beq.s .reloc_ted
  926.     cmp.w #G_FBOXTEXT,d3
  927.     bne.s .no_reloc_ted
  928.  
  929. .reloc_ted:    add.l d7,ob_spec(a2)
  930.  
  931. .no_reloc_ted:
  932.  
  933.     cmp.w #G_IMAGE,d3
  934.     beq.s .reloc_classique
  935.     cmp.w #G_BUTTON,d3
  936.     beq.s .reloc_classique
  937.     cmp.w #G_STRING,d3
  938.     beq.s .reloc_classique
  939.     cmp.w #G_ICON,d3
  940.     beq.s .reloc_classique
  941.     cmp.w #G_TITLE,d3
  942.     beq.s .reloc_classique
  943.     cmp.w #G_CICON,d3
  944.     bne.s .reloc_done
  945.  
  946.     move.l ob_spec(a2),d4
  947.     lsl.l #2,d4
  948.     move.l a0,a3
  949.     add.w rsh_rssize(a0),a3
  950.     lea ([4,a3],a0.l),a3    ; ptr table de ptrs sur les Cicons blk
  951.     move.l (a3,d4.l),ob_spec(a2)
  952.     bra.s .reloc_done
  953.  
  954. .reloc_classique:
  955.     add.l d7,ob_spec(a2)
  956.  
  957. .reloc_done:
  958. .pas_reloc_struct:
  959.  
  960.     save.l d0-d2/d7/a0-a2
  961.     rsrc_obfix -4(a1),d2    ; caractère -> pixel
  962.     load.l d0-d2/d7/a0-a2
  963.  
  964.     move.w ob_head(a2),d3
  965.     bmi.s .pas_de_fils2
  966.  
  967.     move.w d3,d2
  968.     mulu #L_OBJECT,d3
  969.     add.l -4(a1),d3
  970.     move.l d3,a2
  971.     bra.s .next_object
  972.  
  973. .pas_de_fils2:
  974. .next_is_dad:
  975.     move.w d2,d3        ; objet courant
  976.  
  977.     move.w ob_next(a2),d2
  978.     ble.s .pas_de_frere_pere    ; -> le suivant est le root ou le root est tout seul
  979.  
  980.     move.w d2,d4
  981.     mulu #L_OBJECT,d4
  982.     add.l -4(a1),d4
  983.     move.l d4,a2
  984.     cmp.w ob_tail(a2),d3
  985.     beq.s .next_is_dad
  986.  
  987. .next_object:
  988.     bra .parse_all_this_tree
  989. .pas_de_frere_pere:
  990.  
  991.     dbf d0,.parse_all_trees
  992. .nothing4:
  993.     moveq #GWVA_NO_ERROR_GENERIC,d7
  994.     rts
  995.  
  996. .erreur_ressource:
  997.     moveq #GWVA_ERROR_GENERIC,d7
  998.     rts
  999.  
  1000.     *--------------------------*
  1001.  
  1002. .traitement_icones_couleurs:
  1003.     move.l a0,a2
  1004.     add.w rsh_rssize(a0),a2
  1005.     move.l 4(a2),d0
  1006.     lea (a0,d0.l),a2    ; ptr table de ptrs sur les Cicons blk
  1007.  
  1008.     move.l a2,a3
  1009.     moveq #-1,d0
  1010. .count:    addq #1,d0
  1011.     tst.l (a3)+
  1012.     beq.s .count
  1013.             ; a2 pointe sur le premier CICONBLK
  1014.     subq #1,d0        ; nbre d'icone couleur
  1015.  
  1016.     tst d0
  1017.     bmi .no_cicon
  1018.  
  1019. *    cmp.w #2,GWVA_ROOT_VDI_WORKSTATION+39*2    ; nbre de couleur de la station
  1020. *    beq .pas_besoin_icones_couleurs    ; en monochrome, on prend la definition monochrome
  1021.  
  1022.     clr.l d4        ; taille des icones couleurs à réserver
  1023.     clr.l d7        ; taille max d'une icone
  1024. ;
  1025.     save.l d0/a1-a2
  1026.  
  1027. .parse_all_icons1:
  1028.     save.w d0
  1029.  
  1030.     move.l a3,(a2)+
  1031.  
  1032.     move.l a3,a4
  1033.     add.l #L_CICONBLK,a4
  1034.     move ib_wicon(a3),d1
  1035.     ext.l d1
  1036.     divu #16/2,d1
  1037.     mulu ib_hicon(a3),d1        ; d1=taille mono en byte
  1038.     move.l a4,ib_pdata(a3)
  1039.     add.l d1,a4
  1040.     move.l a4,ib_pmask(a3)
  1041.     add.l d1,a4
  1042.     move.l a4,ib_ptext(a3)
  1043.     add.w #12,a4        ; longeur d'un texte
  1044.  
  1045.     move.l mainlist(a3),d2        ; nb_cicon >=1
  1046.     subq.w #1,d2
  1047.  
  1048.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d5    ; nbre de plans affichés
  1049.  
  1050. .find_a_good_resolution_for_this_icone:
  1051.     save.l d2/a4        ; d2 : nbr de résolution, a4 pointe la liste de résolution
  1052.     bsr .parse_all_icone_resolutions
  1053.     move.l a4,a5
  1054.     load.l d2/a4
  1055.  
  1056.     tst d0
  1057.     beq.s .good_resolution_found
  1058.  
  1059.     lsr.w #1,d5        ; 8 -> 4 -> 2 -> 1 plans ...
  1060.     tst d5
  1061.     bne .find_a_good_resolution_for_this_icone
  1062.  
  1063.     lea 0.w,a5        ; pas d'icone couleur correspondant a la résolution souhaitée
  1064. .good_resolution_found:
  1065.     move.l a5,mainlist(a3)    ; on pointe directement sur l'icone correspondant le mieux à la résolution souhaitée
  1066.  
  1067.     move.w #-1,d5    ; pour passer les définitions de cette icone
  1068.     bsr .parse_all_icone_resolutions
  1069.     move.l a5,a3    ; icone suivante
  1070.  
  1071.     load.w d0
  1072.     dbf d0,.parse_all_icons1
  1073.  
  1074.     load.l d0/a1-a2
  1075.  
  1076.     tst.l d4        ; reservation memoire ?
  1077.     bne.s .malloc_icone
  1078.  
  1079.     tst.l d7
  1080.     bne.s .malloc_transfert
  1081.  
  1082.     bra.s .pas_de_malloc
  1083.  
  1084. .malloc_icone:
  1085.     save.l d0/d7/a0-a2
  1086.     MXALLOC #MX_PREFTTRAM,d4
  1087.     move.l d0,d1
  1088.     load.l d0/d7/a0-a2
  1089.     move.l d1,(a1)
  1090. .malloc_transfert:
  1091.     save.l d0/a0-a2
  1092.     add.l d7,d7        ; pour la selection eventuelle
  1093.     MXALLOC #MX_PREFTTRAM,d7
  1094.     move.l d0,d1
  1095.     load.l d0/a0-a2
  1096.     move.l d1,4(a1)
  1097. .pas_de_malloc:
  1098.  
  1099.  
  1100. *.pas_besoin_icones_couleurs:
  1101.  
  1102.     move.l (a1),d4    ; adresse du malloc pour les icones couleurs
  1103.  
  1104. .parse_all_icons2:
  1105.     move.l (a2)+,a3
  1106.  
  1107. *    move.l a3,a4
  1108. *    add.l #L_CICONBLK,a4        ; ?_ERROR_? (lignes ->    move.l mainlist(a3),a4        ; on pointe directement sur la bonne icone
  1109.     move ib_wicon(a3),d1
  1110.     ext.l d1
  1111.     divu #16/2,d1
  1112.     mulu ib_hicon(a3),d1        ; d1=taille mono en byte
  1113.     
  1114.     move.l mainlist(a3),a4        ; on pointe directement sur la bonne icone
  1115.     cmp.l #0,a4
  1116.     beq .pas_definition_couleur
  1117.  
  1118.     move.w d1,d3        ; taille mono
  1119.     mulu num_planes(a4),d3        ; d3.l taille icone couleur
  1120.  
  1121.     move.l col_data(a4),a5
  1122.     move.l 4(a1),d7
  1123.     bsr .cree_resolution_icone
  1124.  
  1125.     move d1,d5
  1126.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d5
  1127.     add.l d5,d7
  1128.  
  1129.     tst.l sel_data(a4)
  1130.     beq.s .pas_icone_selectionnee2
  1131.  
  1132.     move.l sel_data(a4),a5
  1133.     bsr .cree_resolution_icone
  1134.  
  1135. .pas_icone_selectionnee2:
  1136.  
  1137.     move.w num_planes(a4),d5
  1138.  
  1139.     cmp.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d5
  1140.     beq.s .transformation_en_place
  1141.  
  1142.     move.l d4,col_data(a4)        ; adresse de stockage finale
  1143.     move d1,d6
  1144.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d6
  1145.     add.l d6,d4
  1146. .transformation_en_place:
  1147.  
  1148.     save.l d4-d5
  1149.  
  1150.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,num_planes(a4)
  1151.     move.l 4(a1),d4        ; source icone
  1152.     move.l col_data(a4),d5        ; destination
  1153.     
  1154.     bsr .remets_plans_entrelaces_en_place
  1155.  
  1156.     load.l d4-d5
  1157.  
  1158.     tst.l sel_data(a4)
  1159.     beq.s .pas_icone_selectionnee3
  1160.  
  1161.     cmp.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d5
  1162.     beq.s .transformation_en_place2
  1163.  
  1164.     move.l d4,sel_data(a4)
  1165.     move d1,d6
  1166.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d6
  1167.     add.l d6,d4
  1168. .transformation_en_place2:
  1169.  
  1170.     save.l d4
  1171.  
  1172.     move.l 4(a1),d4
  1173.     move d1,d5
  1174.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d5
  1175.     add.l d5,d4                ; source
  1176.     move.l sel_data(a4),d5            ; destination
  1177.  
  1178.     bsr .remets_plans_entrelaces_en_place
  1179.  
  1180.     load.l d4
  1181.  
  1182. .pas_icone_selectionnee3:
  1183.     clr.l next_res(a4)
  1184.  
  1185. .pas_definition_couleur:
  1186. *.pas_icones_couleurs:
  1187.  
  1188.     dbf d0,.parse_all_icons2
  1189.  
  1190.     tst.l 4(a1)
  1191.     beq.s .pas_buffer_temp
  1192.     save.l a0-a1
  1193.     MFREE 4(a1)
  1194.     load.l a0-a1
  1195.     clr.l 4(a1)
  1196. .pas_buffer_temp:
  1197.  
  1198. .no_cicon:
  1199.     rts
  1200.  
  1201.     *--------------------------------------*
  1202. .parse_all_icone_resolutions:
  1203. ; d1.w : taille icone mono
  1204. ; d4.l=0
  1205. ; d5.w : résolution souhaitée
  1206. ; d7.l=0
  1207. ; a4.l : pointeur liste des résolutions
  1208.     move.w d1,d3        ; taille mono
  1209.     mulu num_planes(a4),d3        ; d3.l taille icone couleur
  1210.     move.l a4,a5
  1211.     add.l #L_CICON,a5
  1212.     move.l a5,col_data(a4)
  1213.     add.l d3,a5
  1214.     move.l a5,col_mask(a4)
  1215.     add.l d1,a5
  1216.  
  1217. ; Est-ce une icone de la resolution recherchée ?
  1218.     cmp.w num_planes(a4),d5
  1219.     bne.s .saute_icone_couleur1
  1220.  
  1221.     save.l d0
  1222.  
  1223.     move d1,d0
  1224.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d0    ; d0.l taille icone couleur à la résolution de la station
  1225.  
  1226. ; Est-ce une icone directement affichable ?
  1227.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d6
  1228.     cmp.w num_planes(a4),d6
  1229.     beq.s .pas_de_reservation1    ; transformation en place si icone de meme résolution
  1230.  
  1231. ; Il faut reserver la place de l'icone
  1232.     add.l d0,d4
  1233.  
  1234. .pas_de_reservation1:
  1235.     cmp.l d0,d7
  1236.     bge.s .max_taille_icone
  1237.     move.l d0,d7
  1238. .max_taille_icone:
  1239.  
  1240.     load.l d0
  1241. .saute_icone_couleur1:
  1242.  
  1243.     tst.l sel_data(a4)
  1244.     beq.s .pas_icone_selectionee
  1245.  
  1246.     move.l a5,sel_data(a4)
  1247.     add.l d3,a5
  1248.     move.l a5,sel_mask(a4)
  1249.     add.l d1,a5
  1250.  
  1251.     cmp.w num_planes(a4),d5
  1252.     bne.s .saute_icone_couleur2
  1253.  
  1254.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d6
  1255.     cmp.w num_planes(a4),d6
  1256.     beq.s .pas_de_reservation2        ; transformation en place si icone de meme résolution
  1257.  
  1258.     move d1,d6
  1259.     mulu GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d6
  1260.     add.l d6,d4
  1261. .pas_de_reservation2:
  1262.  
  1263. .saute_icone_couleur2:
  1264. .pas_icone_selectionee:
  1265.  
  1266.     cmp.w num_planes(a4),d5
  1267.     beq.s .end_good_resolution_found
  1268.  
  1269.     move.l a5,a4        ; résolution suivante
  1270.     dbf d2,.parse_all_icone_resolutions
  1271.  
  1272.     move.w #-1,d0        ; pas de résolution
  1273.     rts
  1274. .end_good_resolution_found:
  1275.     clr.w d0
  1276.     rts
  1277.  
  1278.     *--------------------------------------*
  1279.  
  1280. .cree_resolution_icone:
  1281.     move.l d7,a6
  1282.     move.l d3,d6
  1283.     lsr.l #1,d6
  1284. .recopie_icone:
  1285.     move.w (a5)+,(a6)+
  1286.     subq.l #1,d6
  1287.     bne.s .recopie_icone
  1288.  
  1289.     save.w d0
  1290.  
  1291.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d0
  1292.     sub.w num_planes(a4),d0
  1293.     beq.s .pas_de_plan_en_plus
  1294.  
  1295.     move.l d7,a5    ; zone de recopie
  1296.     move.w d1,d6    ; taille d'un plan
  1297.     sub.w #1,d6
  1298. .cree_plans_icone:
  1299.     move.l a5,a6
  1300.     move.w (a5)+,d5
  1301.     move.w num_planes(a4),d0
  1302.     subq.w #1,d0
  1303. .and_plans:    and.w (a6),d5
  1304.     lea (a6,d1.w),a6
  1305.     dbf d0,.and_plans
  1306.  
  1307.     move.w GWVA_ROOT_VDI_WORKSTATION_EXTD+4*2,d0
  1308.     sub.w num_planes(a4),d0        ; on doit ajoutter des plans vides
  1309.     subq.w #1,d0
  1310. .move_plans:move d5,(a6)
  1311.     lea (a6,d1.w),a6
  1312.     dbf d0,.move_plans
  1313.  
  1314.     dbf d6,.cree_plans_icone
  1315.  
  1316. .pas_de_plan_en_plus:
  1317.     load.w d0
  1318.     rts
  1319.  
  1320.     *--------------------------------------*
  1321. .remets_plans_entrelaces_en_place:
  1322.     lea GWVA_ROOT_MFDB_SRC,a5
  1323.     move.l d4,(a5)+        ; pointeur image
  1324.     move.l ib_wicon(a3),(a5)+    ; largeur/hauteur image pixel
  1325.     move.w ib_wicon(a3),d6
  1326.     add.w #15,d6
  1327.     ext.l d6
  1328.     divu #16,d6
  1329.     move.w d6,(a5)+        ; largeur image en mots
  1330.     move.w #1,(a5)+        ; device independent
  1331.     move.w num_planes(a4),(a5)+
  1332.     clr.w (a5)+            ; reservés
  1333.     clr.w (a5)+
  1334.     clr.w (a5)+
  1335.  
  1336.     lea GWVA_ROOT_MFDB_DEST,a5
  1337.     move.l d5,(a5)+        ; pointeur image
  1338.     move.l ib_wicon(a3),(a5)+    ; largeur/hauteur image pixel
  1339.     move.w ib_wicon(a3),d6
  1340.     add.w #15,d6
  1341.     ext.l d6
  1342.     divu #16,d6
  1343.     move.w d6,(a5)+        ; largeur image en mots
  1344.     move.w #0,(a5)+        ; device dependent
  1345.     move.w num_planes(a4),(a5)+
  1346.     clr.w (a5)+            ; reservés
  1347.     clr.w (a5)+
  1348.     clr.w (a5)+
  1349.  
  1350.     save.l d0-d3/a0-a4
  1351.     vr_trnfm #GWVA_ROOT_MFDB_SRC,#GWVA_ROOT_MFDB_DEST
  1352.     load.l d0-d3/a0-a4
  1353.     rts
  1354.  
  1355.     *--------------------------------------*
  1356. .reloc_array:
  1357.     move.l a0,a1
  1358.     move.l a0,d7
  1359.     add.w (a0,d1.w),a1
  1360.     subq #1,d0
  1361.     bmi.s .nothing
  1362. .reloc_array2:
  1363.     add.l d7,(a1)+
  1364.     dbf d0,.reloc_array2
  1365. .nothing:    rts
  1366.  
  1367.     endc    ; ifd MDL_RELOCATE_RSC
  1368.  
  1369. ;------------------------------------------------------------------------------
  1370.  
  1371.     BSS
  1372.  
  1373. GWVA_RSC_TMP_ADD_TREE:    ds.l 1
  1374.  
  1375.     TEXT
  1376.